Themabewertung:
  • 0 Bewertung(en) - 0 im Durchschnitt
  • 1
  • 2
  • 3
  • 4
  • 5
Zeiträume vergleichen und addieren
#1
Hallo in die Runde!
Ich habe im Excel eine Liste mit Mitarbeitern, Arbeitsbeginndatum, Arbeitsenddatum, sowie die dazugehörigen Uhrzeiten und Arbeitspositionen.

Ich habe 10 Mitarbeiter in der Liste die einzeln angeführt sind.
An Position 630 haben 3 Mitarbeiter Dienst von 18h00 bis 03h00 und 2 Mitarbeiter von 20h00 bis 03h00.
An Position 631 hat 1 Mitarbeiter Dienst von 18h00 bis 03h00 und 4 Mitarbeiter von 20h00 bis 03h00.

Im Angehängten Beispiel würde ich gerne folgendes erreichen:
Ich würde gerne eine Berechnung und Darstellung erzielen die mir pro Position und nach Zeiträumen die Anzahl an Mitarbeitern anzeigt.

In diesem Fall müsste das Ergebnis sein:

Position 630
18h00-03h00: 3 Mitarbeiter
20h00-03h00: 5 Mitarbeiter

Position 631
18h00-03h00: 1 Mitarbeiter
20h00-03h00: 4 Mitarbeiter


Ist das abbildbar.

Vielen Dank für eure Unterstützung.

Liebe Grüsse


Angehängte Dateien
.xlsx   Excel Mitarbeiter.xlsx (Größe: 5,16 KB / Downloads: 7)
Zitieren
#2
H1#:

=LET(
x;A2:G11;u;ZEILEN(x);
y;SPALTENWAHL(x;3)+SPALTENWAHL(x;4);z;SPALTENWAHL(x;5)+SPALTENWAHL(x;6);
a;MIN(y);b;MAX(z);t;(b-a)*24;c;SEQUENZ(;t+1;a;1/24);d;WEGLASSEN(c;;-1);e;WEGLASSEN(c;;1);
VSTAPELN(d;--(0<RUNDEN(MATRIXERSTELLEN(u;t;LAMBDA(zz;ss;MAX(;MIN(INDEX(e;ss);INDEX(z;zz))-MAX(INDEX(d;ss);INDEX(y;zz)))));2))))


als Zwischenstufe (und Kontrolle). Ich könnte auch noch weitermachen.
Manchmal muss man Menschen aufgeben. Nicht, weil sie Dir egal sind, sondern weil Du es ihnen bist.
Zitieren
#3
Hi Lupo 1!

Vorab erstmals VIELEN DANK! Allerdings überschreitet dies meine Kenntnisse bei weitem. Könntest du mir dies netterweise in die hochgeladene Excel eintragen, da ich mich sonst nicht auskenne.
Und kannst du mir bitte erklären was du mit deinem philosopischen Zusatz ausdrücken wolltest?

Vielen Dank für deine Unterstützung.

Liebe Grüsse
Zitieren
#4
Der Zusatz steht in der Signatur. Hat also nix mit Dir zu tun Wink Den Inhalt verstehst Du aber?


Angehängte Dateien
.xlsx   Excel Mitarbeiter.xlsx (Größe: 10,51 KB / Downloads: 3)
Manchmal muss man Menschen aufgeben. Nicht, weil sie Dir egal sind, sondern weil Du es ihnen bist.
Zitieren
#5
Vielen Dank! Das hilft schon weiter! 
Übersteigt jedoch mein Excel Wissen bei weitem

Jetzt haben ich noch zwei Punkte:
Die Ergebnisse sind aktuell falsch. Bei 630 müsste 3 und 5 rauskommen und bei 631 müsste es 4 und 1 sein. Könntest du mich da noch unterstützen bitte.
Und Zweitens: Gibt es eine Möglichkeit, dass ich das nicht eingeben muss sondern mir aus einer Liste die so ausschaut wie diese die ich dir geschickt habe, jedoch viel länger ist, eine neu Liste zu machen je Position und Zeiträumen. Sprich eine Zeitraumauswertung nach Position?

DANKE
Zitieren
#6
In der Datei hatte ich in einer Zeile die Datümer abgewandelt. Die Ergebnisse waren also nicht falsch.

Bei 631 ist 1 und 5 absolut korrekt. Warum rechnest Du dort anders, als bei 630? Es geht immer um die jeweilige Summe.

Das, was Du möchtest, ist mir schon klar. Erfordert allerdings mehrere Konzeptänderungen. Vielleicht habe ich ja noch Lust.
Manchmal muss man Menschen aufgeben. Nicht, weil sie Dir egal sind, sondern weil Du es ihnen bist.
Zitieren
#7
Das würde, ich sehr freuen wenn du mir da noch mehr helfen könntest!!!

Liebe Grüsse
M
Zitieren
#8
Hi,

oder auch so:


.xlsx   Excel Mitarbeiter.xlsx (Größe: 8,63 KB / Downloads: 7)
Zitieren
#9
Habe jetzt eine Standardfunktion INTERVAL_COUNT gebastelt.

Hier (z.B. in I1) ohne Benennung einfach eintragen und die entsprechende Spalte als DatumZeit formatieren:

=LAMBDA(Bereich;LET(
xx;Bereich;
y;ZEILEN(xx);
x;WENN(SPALTEN(xx)=3;xx;HSTAPELN(SEQUENZ(y;;1;0);xx));
a;INDEX(x;;1);
b;INDEX(x;;2);
c;INDEX(x;;3);
f;SORTIEREN(EINDEUTIG(VSTAPELN(HSTAPELN(a;b);HSTAPELN(a;c)));{1.2});
h;WEGLASSEN(INDEX(f;;2);-1);
i;WEGLASSEN(INDEX(f;;2);1);
j;NACHZEILE(MATRIXERSTELLEN(ZEILEN(h);y;LAMBDA(z;s;(INDEX(f;z;1)=INDEX(a;s))*MAX(;MIN(INDEX(i;z);INDEX(c;s))-MAX(INDEX(h;z);INDEX(b;s)))));LAMBDA(x;SUMME(x)))/(i-h);
HSTAPELN(f;VSTAPELN(j;0))))(HSTAPELN(G2:G11;C2:C11+D2:D11;E2:E11+F2:F11))


ergibt

630 05.07.2023 18:00 3
630 05.07.2023 20:00 5
630 06.07.2023 03:00 0
631 05.07.2023 18:00 1
631 05.07.2023 20:00 5
631 06.07.2023 03:00 0
Manchmal muss man Menschen aufgeben. Nicht, weil sie Dir egal sind, sondern weil Du es ihnen bist.
Zitieren
#10
Hi! 
Hoffe du hattest ein schönes Wochenende!
Sorry für die verspätetet Antwort aber ich war ein paar Tage auf Urlaub.
Ich schaue es mir heute Abend sofort an.

VIELEN VIELEN DANK vorbab und ich darf mich bei dir melden.

Liebe Grüsse
M
Zitieren


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste




Hinweis auf Angebot Excel-Inside - lang    Keine Lösung gefunden? Du kannst Dich gerne an unser erfahrenes Experten-Team wenden um dein Anliegen zu besprechen.
   Gerne erstellen wir auf dieser Basis ein Angebot.
   Sende deine Anfrage einfach
per E-Mail an anfrage@excel-inside.de


Powerd and supported by Excel-InsideSolutions