Excel Tabelle Text aus Zelle in Formel übertragen

[UllrichBaltzer]

Hallo,
für folgendes Problem habe ich keine Lösung gefunden.
In der erstellten Tabelle (siehe Bild) möchte ich in der Zelle "Ergebnis (E2)" den "Wert (A2)" mit der "Summe (D2)" addieren bzw. subtrahieren je nach dem was in der Zelle "+/- (B2)" steht. Bei der Standardformel "=SUMME(A2-D2)" möchte ich das "-" durch das Zeichen (+oder-) aus der Zelle "B2" ersetzen. Geht das? Und was muß ich in die Formel eintragen um das zu erreichen?

vielen Dank im Vorraus für eine Antwort

mit besten Grüßen an die Fachwelt
Ullrich Baltzer

[{Boris}]

Hi,

das geht z.B. mit der alten Excel4Makrofunktion AUSWERTEN.
Selektiere Zelle E2, dann Strg+F3 (Namen definieren) - Neu - Name: Ullrich
Bezieht sich auf:
=AUSWERTEN($A2&$B2&$D2)

In Zelle E2 schreibst Du nun:
=Ullrich

Wenn Du die Formel dann runterkopierst, wandert die Zeile mit - also auf Zeile 3, 4 etc.

Hinweis: Die Mappe ist damit xlsm-pflichtig.

VG, Boris

[{Boris}]

Hi,

noch etwas flexibler bist Du mit LAMBDA.
Definiere wieder einen Namen (Strg+F3), Neu, Name: Rechne
Bezieht sich auf:
=LAMBDA(WertX;Rechenzeichen;WertY;AUSWERTEN(WertX&Rechenzeichen&WertY))

In der Tabelle dann anzuwenden nach folgender Syntax:

=Rechne(WertX;Rechenzeichen;WertY)

Also bezogen auf Dein Bildbeispiel in E2 dann:

=Rechne(A2;B2;D2)

VG, Boris

[RPP63]

Moin!
Das Gleiche erreichst Du "etwas" einfacher mit
=A2+(B2&D2)


Gruß Ralf

[{Boris}]

Moin Ralf,

für + und - hast Du natürlich Recht - und hier sollte das ja auch reichen. Die andere Variante kann aber auch dividieren, multiplizieren und potenzieren - da war ich gedanklich etwas "universeller" (in diesem Fall zu universell) unterwegs ;-)

[UllrichBaltzer]

Vielen Dank für die schnelle und kompetente Hilfe!  
Funktioniert auch in der Kombination mit "WENN" gut.
=WENN(A2="";"";SUMME(A2+(B2&D2)))

Nochmal Dank an die Fachwelt!!!!

[RPP63]

Vielen Dank für die schnelle […] Hilfe!  

Vielen Dank für die schnelle Antwort!
Was sind schon 5 Wochen …
Das SUMME() um meinen Term A2+(B2&D2) ist übrigens flüssiger als Wasser!
Excel wertet Formeln immer "von innen nach außen" aus:
B2&D2 ergibt "-80,85" (also einen Text) 
385+"-80,85" (Excel wandelt den Text "-80,85" implizit in die Zahl -80,85 um, weil addiert werden soll)
385-80,85 ergibt 304,15
Aus dieser einzelnen Zahl 304,15 möchtest Du jetzt eine Summe bilden …
Kämst Du jemals auf die Idee, =SUMME(2) auszurechnen?

Fragt sich
Ralf