Zelleninhalt teilweise übernehmen

[Lia773598]

Hallo zusammen,

ich möchte einen Zelleninhalt nur teilweise in die Zelle daneben übernehmen. Also in meiner Zelle 1 steht z.B. https://office-fragen.de
Und ich möchte in der Zelle daneben nur den Teil office-fragen angezeigt bekommen.
Meine Tabelle hat leider noch die Besonderheit, dass die Zellen sich unterschiedlich beginnen:

http://
https://
https://www.
http://www.

Und ich möchte aber immer nur den mittleren Teil angezeigt bekommen. Also zwischen // und . beziehungsweise zwischen . und .

Hat jemand eine Lösung?

Vielen Dank!

[Calderon]

Hallo,
das wäre mit Teil(), Wechseln(), Finden() schon machbar.

Was ist wenn etwas anderes als "www." vor der Domain steht?

=TEIL(WECHSELN(A1;"www.";"");FINDEN("://";A1)+3;FINDEN(".";WECHSELN(A1;"www.";""))-FINDEN("://";A1)-3)

[Lia773598]

Hallo,
das wäre mit Teil(), Wechseln(), Finden() schon machbar.

Was ist wenn etwas anderes als "www." vor der Domain steht?

=TEIL(WECHSELN(A1;"www.";"");FINDEN("://";A1)+3;FINDEN(".";WECHSELN(A1;"www.";""))-FINDEN("://";A1)-3)

Wow!
Es funktioniert!

Vielen lieben Dank!!!

Die Situation, dass etwas anderes als ://www. oder :// vor der Domain steht habe ich nicht.
Ich habe deine Funktion gerade getestet und sie funktioniert einwandfrei.

Ich hatte es anfangs auch versucht mit =TEIL
=TEIL(A1;9;15)
Da hat es mir aber immer ab dem 9. Zeichen den Text ausgespuckt, was leider nichts bringt, wenn die Links immer unterschiedlich geschrieben sind.
Und die 15 Zeichen waren teilweise zu kurz um den kompletten Domainnamen anzuzeigen.

[Flotter Feger]

Das geht auch viel kürzer ...

=WECHSELN(TEIL(B3;SUCHEN("//";B3)+2;LÄNGE(B3));"www.";"")

[Calderon]

Die TLDs (".de" oder andere) sollen auch weg.

In der Office - Insiderversion würde es mit folgender Formel funktionieren:
=INDEX(TEXTTEILEN(WECHSELN(A1;"www.";"");"//";".");1;2)

Hilft Lia773598 aber noch nicht.

[Flotter Feger]

übersehen ...

=TEXTVOR(WECHSELN(TEIL(B3;SUCHEN("//";B3)+2;LÄNGE(B3));"www.";"");".";-1)