Themabewertung:
  • 0 Bewertung(en) - 0 im Durchschnitt
  • 1
  • 2
  • 3
  • 4
  • 5
Formel Problem. Zählt nur richtig mit erstem Eintrag
#1
Hallo zusammen,

ich habe ein Problem mit folgender Formel:

=SUMME(N(HÄUFIGKEIT(ZEILE(3:8059);TEILERGEBNIS(3;INDIREKT("G"&ZEILE(3:8059)))*VERGLEICH(G3:G8059&"";G3:G8059&""Wink)>0))

Ich möchte in einer Spalte unterschiedliche Länder zählen und doppelte ausschließen + beim Filtern nur die Anzahl der gefilterten anzeigen lassen.

Beispiel:

Deutschland
Deutschland
Deutschland
Belgien
Belgien
Niederlande


Anzeige = 3

Soweit so gut. Das klappt mit der oberen Formel nur, wenn nicht gefiltert wird (Gesamtergebnis stimmt) oder wenn der erste Eintrag (in dem Beispiel "Deutschland") mitgezählt wird.
Filter ich also Deutschland und Niederlande, stimmt das Ergebnis (2). Filtere ich aber ohne den ersten Eintrag, also Belgien und Niederlande ist das Ergebnis "3".

Somit muss ich immer 1 abziehen wenn Deutschland im Filter nicht enthalten ist. Kennt jemand dieses Problem und kann mir helfen es zu lösen?
Zitieren
#2
Hallo,

lade doch bitte eine Datei hoch, ich komme auf ein ganz andres Ergebnis.

Mit Hilfsspalte oder Pivot Tabelle wäre es einfacher.
Gruß Kalk
Zitieren
#3
Anbei die Tabelle.


Angehängte Dateien
.xlsx   test.xlsx (Größe: 530,14 KB / Downloads: 7)
Zitieren
#4
Moin

Code:
=SUMME(N(HÄUFIGKEIT(ZEILE(3:8059)-2;TEILERGEBNIS(3;INDIREKT("G"&ZEILE(3:8059)))*VERGLEICH(G3:G8059&"";G3:G8059&"";))>0))-1
Wir sehen uns!
... Detlef

Meine Beiträge können Ironie oder Sarkasmus enthalten.
Zitieren
#5
(26.11.2022, 12:53)DL schrieb: Moin

Code:
=SUMME(N(HÄUFIGKEIT(ZEILE(3:8059)-2;TEILERGEBNIS(3;INDIREKT("G"&ZEILE(3:8059)))*VERGLEICH(G3:G8059&"";G3:G8059&"";))>0))-1

Danke! Darf ich fragen was die -2 im ersten Befehl zu bedeuten hat? Ich habe vorher immer mit der -1 am Ende experimentiert aber das stimmte dann natürlich nicht wenn ich den ersten Eintrag mit drin hatte.
Zitieren
#6
Der kleinste mögliche Wert von VERGLEICH() ist 1 - die erste Position in der Liste.
Der kleinste mögliche Wert von ZEILE(3:8059) ist 3.
Das ist eine Differenz von 2.
Wir sehen uns!
... Detlef

Meine Beiträge können Ironie oder Sarkasmus enthalten.
Zitieren
#7
In Spalte B dieser Tabelle habe ich ebenfalls Einträge die sich doppeln und genau so gefiltert und angezeigt werden sollen wie bei der Länderspalte, also habe ich die gleiche Formel genutzt:


Code:
=SUMME(N(HÄUFIGKEIT(ZEILE(3:8059)-2;TEILERGEBNIS(3;INDIREKT("B"&ZEILE(3:8059)))*VERGLEICH(B3:B8059&"";B3:B8059&"";))>0))-1


Das Ergebnis ist hier allerdings, dass er nun von der Gesamtanzahl 1 abzieht, weil er plötzlich den letzten Eintrag auf Zeile 8059 nicht mitzählt. Filtere ich nur diesen Eintrag von Zeile 8059, ist das Ergebnis 0 statt 1.
Ich habe nun "provisorisch" im ersten Schritt der Formel um 1 erhöht: =SUMME(N(HÄUFIGKEIT(ZEILE(3:8060)-2;... und den Rest so gelassen, nun stimmt es zwar aber richtig erscheint mir das nicht.
Zitieren
#8
Neuer Versuch.

Code:
=SUMME(--(HÄUFIGKEIT(WENN(TEILERGEBNIS(3;INDIREKT("H"&ZEILE(H3:H29)))=0;"";WENN(H3:H29="";"";VERGLEICH(H3:H29&"";H3:H29&"";0)));ZEILE(H3:H29)-2)>0))

Ich würde aber dies vorziehen:
Code:
=ANZAHL2(EINDEUTIG(FILTER(H3:H29;TEILERGEBNIS(3;INDIREKT("H"&ZEILE(H3:H29))))))
Wir sehen uns!
... Detlef

Meine Beiträge können Ironie oder Sarkasmus enthalten.
Zitieren
#9
(28.11.2022, 21:35)DL schrieb: Neuer Versuch.

Code:
=SUMME(--(HÄUFIGKEIT(WENN(TEILERGEBNIS(3;INDIREKT("H"&ZEILE(H3:H29)))=0;"";WENN(H3:H29="";"";VERGLEICH(H3:H29&"";H3:H29&"";0)));ZEILE(H3:H29)-2)>0))

Ich würde aber dies vorziehen:
Code:
=ANZAHL2(EINDEUTIG(FILTER(H3:H29;TEILERGEBNIS(3;INDIREKT("H"&ZEILE(H3:H29))))))

Bei der ersten Formel zeigt er am Ende "#Wert!" an und bei der Zweiten kommt eine Fehlermeldung. "Diese Funktion ist ungültig. Er markiert dabei das Wort "Filter" in der Formel.
Schade, aber vielen Dank für deine Arbeit, dass hat mir dennoch sehr geholfen.
Zitieren
#10
Punkt 1: Eingabe mit STRG+UMSCHALT+ENTER.
Punkt 2: Das war mir klar. Sollte eine Motivation sein. Damit fällt auch Punkt 1 weg.
Wir sehen uns!
... Detlef

Meine Beiträge können Ironie oder Sarkasmus enthalten.
Zitieren


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste




Hinweis auf Angebot Excel-Inside - lang    Keine Lösung gefunden? Du kannst Dich gerne an unser erfahrenes Experten-Team wenden um dein Anliegen zu besprechen.
   Gerne erstellen wir auf dieser Basis ein Angebot.
   Sende deine Anfrage einfach
per E-Mail an anfrage@excel-inside.de


Powerd and supported by Excel-InsideSolutions