Nullen in der Mitte der Zelle entfernen

[Mike]

Hallo,

ich benötige Eure Hilfe und wäre Euch sehr dankbar wenn Sie mir eine Lösung anbieten. 

Ich möchte die Nullen in der Mitte des Zellenstrings der Spalte A entfernen:


IST:
SPALTE A:
**********
AB1200C11
KL023V0
BC000T1
AK0T200
N018000
A0001
B01

SOLL:
SPALTE A:
**********
AB12C11
KL23V0
BCT1
AKT200
N18000
A1
B1


LG, Mike

[DL]

Moin Mike

In welcher Situation braucht man das?

[maninweb]

Hallo,

beispielsweise so ...

PHP-Code:

B1=WENN(LÄNGE(A1)>2;LINKS(A1;1)&WECHSELN(TEIL(A1;2;LÄNGE(A1)-2);"0";"")&RECHTS(A1;1);"") 


Nachtrag: Nein, passt doch so nicht, z.B. für N018000.

Gruß

[maninweb]

Hallo,

Du könntest folgende Formel mal probieren. In einer modernen Excel-Version dürfte das einfacher sein.
Die Formel habe ich jetzt zudem nicht ausführlich gestestet, passt aber für die Beispieldaten.

PHP-Code:

B1=WENN(WENNFEHLER(FINDEN("0";A1);0)>0;WENN(LÄNGE(WECHSELN(RECHTS(A1;LÄNGE(A1)-FINDEN("0";A1));"0";""))>0;
   TEIL(A1;1;FINDEN("0";A1)-1)&RECHTS(RECHTS(A1;LÄNGE(A1)-FINDEN("0";A1));
   LÄNGE(RECHTS(A1;LÄNGE(A1)-FINDEN("0";A1)))-FINDEN(LINKS(WECHSELN(TEXT(RECHTS(A1;LÄNGE(A1)-
   FINDEN("0";A1));"@");"0";"");1);RECHTS(A1;LÄNGE(A1)-FINDEN("0";A1)))+1);TEIL(A1;1;FINDEN("0";A1)-1)&
   RECHTS(A1;LÄNGE(A1)-FINDEN("0";A1)+1));A1) 


Gruß

[DL]

Moin

Obwohl ge-LET-et immer noch zu lang für mein Gefühl.

Code:

=LET(
_l;LÄNGE(A1);
_s1;SEQUENZ(_l);
_s2;SEQUENZ(_l;;_l;-1);
_t1;TEIL(A1;_s1;_s2);
_wi;WIEDERHOLEN(0;_s2);
_prf1;_t1<>_wi;
_t2;TEIL(A1;_s1;1);
_prf2;(_t2="0");
_prf3;_prf1*_prf2;
_we;WENN(_prf1;WECHSELN(_t2;0;"");_t2);
TEXTKETTE(_we))

[maninweb]

Moin,

meine Lösung würde so aussehen, die aber dann auch etwas länger ist ...

PHP-Code:

=LET(Bezug;A1;N;SEQUENZ(LÄNGE(Bezug));A;WENN(TEIL(Bezug;N;1)<>"0";N;"");
 F;FILTER(A;A<>"");M;WENN(MAX(F)<LÄNGE(Bezug);LET(E;SEQUENZ(LÄNGE(Bezug)-MAX(F);1;MAX(F)+1);VSTAPELN(F;E));F);
 TEXTKETTE(TEIL(Bezug;M;1))) 


Gruß

[Mike]

# DL:  Vielen Dank !
# maninweb: Vielen Dank !

Ich habe Office 2013 Pro plus. Ich bin aber leider nicht der Guru in Excel. Wenn ich irgendwo versuche die Funktion von maniweb einzufügen bekomme ich einen Fehler "Funktion ist ungültig" . Es tut mir leid für diese Frage. Wie soll ich hier vorgehen ?



LG, Mike

[DL]

Meine Lösung und die zweite Lösung von maninweb sind nicht für deine Version zugelassen.

[Mike]

Sehr schade! Dann muss unsere Firma sich damit abfinden.Ich möchte noch einmal Euch einen großen Dank aussprechen!

[maninweb]

Hallo,

hast Du denn die Formel B1=WENN(WENNFEHLER(FINDEN("0";A1);0)>0;WENN ... ... ... aus meinem zweiten Beitrag probiert?

Gruß