Hallo Zusammen,
ich habe eine spalte B mit "Wert" die Differenzen anzeigt, wenn es welche gibt.
In Spalte A Habe ich Länder. In dem Beispiel A und B
Nun möchte ich mir auch ein Teilergebnis der Anzahl der Abweichungen in Spalte B anzeigen lassen, wenn ich nach Land a oder b Filter. DOCH dies klappt irgendwie nicht.
Hat jemand eine Idee, wie ich dies in Zelle b1 hinbekomme.
Im Anhang eine Beispieldatei.
Vielen Dank
Hallo,
Zitat:Teilergebnis der Anzahl der Abweichungen in Spalte B anzeigen lassen
Dazu sollte man auch die richtige Funktion auswählen:
Code:
=TEILERGEBNIS(102;B4:.B7100)
ABER: es müssen auch die "-" weggefiltert werden!
Es geht auch so:
Code:
=ANZAHL2(FILTER(B3:.B3000;(A3:.A3000="A")*(B3:.B3000<>0)))
(25.03.2026, 20:32)boskobiati schrieb: [ -> ]Hallo,
Zitat:Teilergebnis der Anzahl der Abweichungen in Spalte B anzeigen lassen
Dazu sollte man auch die richtige Funktion auswählen:
Code:
=TEILERGEBNIS(102;B4:.B7100)
ABER: es müssen auch die "-" weggefiltert werden!
Es geht auch so:
Code:
=ANZAHL2(FILTER(B3:.B3000;(A3:.A3000="A")*(B3:.B3000<>0)))
Vielen Dank, aber funktioniert nicht. Habe nicht nur eine Spalte, die gefiltert werden kann sondern mehrere und viele Sachen zur Auswahl. Dann soll mir das in Zelle b1 anzeigen es gibt 4 Abweichungen, 6, 30 oder 132 mit diesen gefilterten Attributen
Hallo,
Zitat:Vielen Dank, aber funktioniert nicht.
Tolle Aussage!
Zitat:Habe nicht nur eine Spalte, die gefiltert werden kann
Dein Problem! Die Lösung passt zur Datei. Wenn die Musterdatei nicht zur Originaldatei passt, dann hast Du etwas falsch gemacht.
Im Übrigen passt Teilergebnis, auch wenn Du 10 Filter hast!
Du mußt auch nicht meinen ganzen Beitrag zitieren! Der steht sowieso im Beitrag.
Hallo,
anbei eine Beispielformel ...
Code:
=SUMMENPRODUKT((B4:B71<>0)*(TEILERGEBNIS(103;BEREICH.VERSCHIEBEN(INDEX(B4:B71;1);ZEILE(B4:B71)-MIN(ZEILE(B4:B71));0))))
Oder halt mit LET ...
Code:
=LET(A;B4:B71;SUMMENPRODUKT((A<>0)*(TEILERGEBNIS(103;BEREICH.VERSCHIEBEN(INDEX(A;1);ZEILE(A)-MIN(ZEILE(A));0)))))
Gruß
(25.03.2026, 20:48)boskobiati schrieb: [ -> ]Hallo,
Zitat:Vielen Dank, aber funktioniert nicht.
Tolle Aussage!
Zitat:Habe nicht nur eine Spalte, die gefiltert werden kann
Dein Problem! Die Lösung passt zur Datei. Wenn die Musterdatei nicht zur Originaldatei passt, dann hast Du etwas falsch gemacht.
Im Übrigen passt Teilergebnis, auch wenn Du 10 Filter hast!
Du mußt auch nicht meinen ganzen Beitrag zitieren! Der steht sowieso im Beitrag.
ok. Dachte gibt eine einheitliche Formel, die Zählenwenn mitzieht, wenn man filtert. Das mit Teilergebnis ist mir klar. Nur steht in jeder Zelle etwas entweder eine 0 alles top oder eine Zahl mit der Abweichung. Gezählt sollen nur die Anzahl der Abweichungen von 0 und dies auch wenn man filtert
Danke an alle. Ich habe die Lösung selbst herausgefunden
=SUMMENPRODUKT(TEILERGEBNIS(2;INDIREKT("AG"&ZEILE(26:1570)))*(AG26:AG1570<>0))
(25.03.2026, 20:51)maninweb schrieb: [ -> ]Hallo,
anbei eine Beispielformel ...
Code:
=SUMMENPRODUKT((B4:B71<>0)*(TEILERGEBNIS(103;BEREICH.VERSCHIEBEN(INDEX(B4:B71;1);ZEILE(B4:B71)-MIN(ZEILE(B4:B71));0))))
Oder halt mit LET ...
Code:
=LET(A;B4:B71;SUMMENPRODUKT((A<>0)*(TEILERGEBNIS(103;BEREICH.VERSCHIEBEN(INDEX(A;1);ZEILE(A)-MIN(ZEILE(A));0)))))
Gruß
Danke dafür. Dies ist dann next Level :-)