Office-Fragen.de

Hallo zusammen,

weiß jemand ob es möglich ist (und wenn ja wie es geht) dass man eine Mitarbeitertabelle die ein Start und Enddatum als Spalte hat mit einer Datumtabelle (mit 12 Daten pro Jahr) verknüpfen kann. Dabei sollen nur die Monate von Anfangs bis Enddatum gewählt werden.

Beispiel:

Aus den 3 Mitarbeitern

[Bild: 2022-10-12-11-31-50-Beispieldatei-xlsx-Excel.png]

Soll sowas entstehen:

[Bild: 2022-10-12-11-36-22-Beispieldatei-xlsx-Excel.png]

Je nach Länderzugehörigkeit würde ich dann noch gerne die jeweilige Anzahl der Arbeitstage hinzufügen, anbei auch eine Beispieldatei.

Über Tipps würde ich mich sehr freuen Smile

Gruß Steffen

Hallo,

vorausgesetzt, Dein Excel kennt die verwendeten Funktionen, kannst Du das mit einer Formel lösen (soweit ich das verstanden habe).
In der Beispieldatei zwei Formeln, eine in K2 und eine in N2. Hier die K2:

PHP-Code:
=LET(Daten;$A$19:$D$21;
 vnMin;JAHR(MIN(INDEX(Daten;SEQUENZ(ZEILEN(Daten));{3.4})));
 vnMax;JAHR(MAX(INDEX(Daten;SEQUENZ(ZEILEN(Daten));{3.4})));
 fnDistribute;LAMBDA(Index;Base;Low;High;LET(V;DATUM(Base;Index;1);WENN((Low>0)*(V>Low-1)*(V<WENN(High>0;High;DATUM(JAHR(Low);12;1))+1);V;0)));
 vnBase;MATRIXERSTELLEN(ZEILEN(Daten);12*(vnMax-vnMin+1)+1;LAMBDA(X;Y;WENN(Y>1;fnDistribute(Y-1;vnMin;INDEX(Daten;X;3);INDEX(Daten;X;4));X)));
 vnMatrix;MATRIXERSTELLEN(ZEILEN(vnBase)*(SPALTEN(vnBase)-1);2;LAMBDA(X;Y;LET(N;SPALTEN(vnBase)-1;P;
 AUFRUNDEN(X/N;0);Q;WENN(REST(X;N)<1;N;REST(X;N));WAHL(Y;INDEX(Daten;P;1);INDEX(vnBase;P;Q+1)))));
 FILTER(vnMatrix;INDEX(vnMatrix;0;2)>0)) 

[attachment=1130]

Gruß

Hi, sieht gut aus vielen Dank, ich versuche mal die Formel zu verstehen Smile

Kennt auch jemand einen etwas leichteren Weg möglicherweise über Power Query?

Gruß

WielandS

maninweb

WielandS